Cosenos directores

Consideremos un astro cuyas coordenadas vienen dadas en ecuatoriales por la Ascensión Recta A y por la Declinación D. Las coordenadas rectangulares vienen dadas por:

x=r.cos D cos A
y=r.cos D sen A
z=r.sen D

ÁNGULO ENTRE DOS ASTROS

La distancia angular d entre dos astros cuya ascensión recta A1 y declinación D1 es conocida se puede saber mediante la expresión:

cos d=senD1 senD2+cosD1 cosD2 cos (A1-A2)

Un applet de Java permite calcular la distancia angular

Análoga expresión es útil si las coordenadas son eclípticas, los correspondientes papeles los desarrollan la longitud y latitud.

También se puede hallar el ángulo a partir de los cosenos directores (a,b,c) de cada astro
cos d= (a1,b1,c1).(a2,b2,c2) siendo . el producto escalar.
Los cosenos directores de cada astro son:

a=x/r=cos D cos A
b=y/r=cos D sen A
c=z/r=sen D

Ejercicio

Probar que el método de los cosenos directores conduce a la expresión inicial.
Si la separación angular es pequeña puede calcularse a partir de:

Es claro que las diferencias en A.R. y Declinación se expresaran en la misma unidad.
Si la diferencia en A.R. se expresa en horas y la diferencia en declinación en grados es útil para obtener d en " de arco:

Ejercicio

Calcular la distancia entre Arturo (Alfa Bootes) y Spica (Alfa Virgen) . Las coordenadas son: A1=14h 13m 22.8s, D1=19°26'31" para Arturo y A2=13h22m33.3s D2=-10°54'03" para Spica.

Ejercicio

La posición de la Luna y Saturno el 26-1-1978 a las 12h es respectivamente: LUNA D=8°21'57" A=10h3m10s , SATURNO D= 13°18'A=10h 5.5m confirmar la expresión Saturno estaba 5° al N de la Luna. SOL: 4°56'
El applet de Java permite calcular la distancia angular

Ejercicio

Calcular la mínima separación en la conjunción de Marte y Júpiter ocurrida el 21 de Enero de 1998 a la 1h de TU.Las coordenadas son: A1=21h 56m 33s, D1=-13°39'33" para Marte y A2=21h 57m 11s D2=-13°24'17" para Júpiter. Solución: 0º 17'50,6"
Un applet de Java permite calcular la distancia angular

Un programa en Basic

El programa calcula el ángulo en ° ' " que forman dos astros cuyas coordenadas se dan en ecuatoriales. Establece la diferencia de calcular el ángulo entre dos astros móviles o entre una estrella fija y un cuerpo que se mueve . En este último caso se prescinde de ingresar por segunda vez las coordenadas del astro fijo. Puede ser útil para calcular las conjunciones planetarias o de un planeta y una estrella o incluso las ocultaciones de una estrella por la Luna si se dispone de las coordenadas topocéntricas lunares. El programa se ha probado con los datos del Practical Astronomy (Minaert) : &31 The angle between two celestial objets , &9 Angular separations.

Listado del programa


10 REM CALCULO ANGULO ENTRE DOS ASTROS

20 CLS:SCREEN 0:PI=3.1415928#

30 PRINT "ANGULO ENTRE DOS ASTROS"

40 DEF FN AC(X)=-ATN (X/SQR(-X*X+1))+PI/2

50 PRINT "ELIJA ENTRE OPCIONES : 1.DOS ASTROS MOVILES"

60 PRINT "                       2.PRIMER ASTRO FIJO Y EL OTRO MOVIL"

70 INPUT X

80 PRINT :PRINT "INGRESE COORDENADAS ECUATORIALES DEL PRIMER ASTRO"

90 GOSUB 230

100 F=A:G=B:H=C

110 PRINT :PRINT "INGRESE COORDENADAS ECUATORIALES DEL SEGUNDO ASTRO"

120 GOSUB 230

130 A1=FNAC(F*A+G*B+H*C)*180/PI

140 GR=INT (A1)

150 M=INT((A1-INT(A1))*60)

160 S=((A1-INT(A1))*60-M)*60

170 PRINT :PRINT "EL ANGULO ENTRE LOS DOS ASTROS ES:    ";

180 PRINT GR;" G ";M;" M ";S;" S "

190 INPUT "OTRO ANGULO (S/N)  ";A$

200 IF A$="N" OR A$="n" THEN 225

210 ON X GOTO 80,110

225 END

230 INPUT "ASCENSION RECTA (H,M,S)=";HH,MM,SS

240 E=(HH+MM/60+SS/3600)*PI/12

250 INPUT "DECLINACION (G,M,S)=";GG,MM,SS

260 IF GG<0 THEN D=-(-GG+MM/60+SS/3600)*PI/180

270 IF GG>=0 THEN D=(GG+MM/60+SS/3600)*PI/180

280 A=COS(D)*COS(E)

290 B=COS(D)*SIN(E)

300 C=SIN(D)

310 RETURN

This HTML document was created by GT_HTML 6.0d 24/01/98 18:22.